Примеры программ на ASSEMBLER. ООО ФРАКТАЛ. Преобразователи - конверторы - интерфейсов промышленная автоматика модульные контроллеры

контрактная разработка, преобразователь интерфейса i2c, преобразователь интерфейса MicroLan, преобразователь интерфейса ModBas, сигма дельта ацп, управление гидравлическими приводами, конвертор интерфейса, конвертор протоколов, конвертор скоростей, макетная плата, промышленная автоматика, модульные контроллеры, basic, микроконтроллер basic, конвертор usb, конвертор rs232, конвертор rs422, конвертор rs485, преобразователь usb, преобразователь rs232, преобразователь rs422, преобразователь rs485, узел автоматики, шаговый двигатель, работа с термодатчиком, подключение ds18, репитер, модули входов, модули гальванической развязки, модуль ацп, модуль цап, модуль индикации, речевой модуль, модуль выходов, графический жки, примеры программ, программируемый логический контроллер
Преобразователь USB | Конвертор интерфейсов USB RS232 RS485 RS422 I2C Microlan Modbus RTU SPI Ethernet | Конверторы протоколов и скоростей | Узлы автоматики | Модульные контроллеры
Главная|Прайс-лист|FAQ|Обмен опытом|Контакты|Новости|DOWNLOAD| | Добавить в избранное | Назад
Комплект модулей MCU4 [ADC4-1.x ]
Комплект модулей MCU4 - ADC4-1.x - Модуль АЦП (сигма-дельта 24 бит до 8 входов с гальванической развязкой; до 8.5кГц при 16 бит)

Примеры программ на ASSEMBLER. ООО ФРАКТАЛ. Преобразователи - конверторы - интерфейсов промышленная автоматика модульные контроллеры
Модуль АЦП (сигма-дельта 24 бит до 8 входов с гальванической развязкой; до 8.5кГц при 16 бит)
Конвертеры интерфейсов [RSX1-4.x ]
Конверторы интерфейсов - RSX1-4.x - Конвертор интерфейсов В корпусе на DIN линейку (RS232C <=> RS422 / RS485)

Примеры программ на ASSEMBLER. ООО ФРАКТАЛ. Преобразователи - конверторы - интерфейсов промышленная автоматика модульные контроллеры
Конвертор интерфейсов В корпусе на DIN линейку (RS232C <=> RS422 / RS485)
Узлы автоматики [MCX51-9.1 DIN ]
Узлы автоматики - MCX51-9.1 DIN - Узел 2-х силовых выходов AC/DC(реле) (AC)250V/8A в 35мм-DIN-конструктиве

Примеры программ на ASSEMBLER. ООО ФРАКТАЛ. Преобразователи - конверторы - интерфейсов промышленная автоматика модульные контроллеры
Узел 2-х силовых выходов AC/DC(реле) (AC)250V/8A в 35мм-DIN-конструктиве

Разделы:

О фирме
 
Продукция
Программы
Справочник
 
Ссылки


RSX4-5.x    Преобразователь USB - RS485

Преобразователь / конвертор интерфейсов USB - RS485
  • Чип моста      CP2104
  • USB 2.0 full-speed (12 Mbps)
  • Поддержка Windows , WinCE, Macintosh, Linux, Android
  • Поддерживаемые форматы данных: 5-8D, 0-1P, 1-1.5-2S
  • Число узлов    до 256
  • Диапазон скоростей    до 1 000 000 bps
  • Длина линии до    1200 м
  • ESD Protection    не менее 15 kV
  • Гальваническая развязка    2500 V rms
  • Галванический зазор      8 мм
  • Индикация
  • Подтяжка сигналов RS485 к питанию 1кОм/1кОм
  • Терминатор      120 Ом
  • Диапазон рабочих температур   -40...+75 Град
  • Размер    52(+13) * 18 * 9(+4)  мм
  •  

    Скачать

    ;******************************************************************************
    ; *
    ; Filename: MCX51-9_2_2.asm *
    ; Date: 8.10.06 *
    ; File Version: 1.02 *
    ; *
    ; Author: Tarasov A.V. *
    ; Company: Fractal *
    ; *
    ;******************************************************************************
    ; Files required: P18F2520.INC *
    ;******************************************************************************
    ;укажем версию и тип процессора
    #DEFINE VERS 0x0102 ;версия программы
    #DEFINE TYPE_PIC 1 ;1 => PIC18F2520

    ;v1.01
    ;проверено на версии 4.24
    ;ЧАСТОТА кварца 32 000 000 Гц
    ;******************************************************************************
    ;RA0-AN вход IN0(X6) ->AN0
    ;RA1-AN вход IN1(X7) ->AN1
    ;RA2-x не используется
    ;RA3-(AN_REF) резерв (опорное напряжение 4.096В)
    ;RA4-IN вход IN0(X6)->T0
    ;RA5-AN (контроль питания делитель 10-1 (U=Uвх/11)
    ;RB0-OUT выход OUT1P(X8-9) -> "1"=выходной ключ включен
    ;RB1-OUT выход OUT1N для второго плеча бистабильного реле(X8-9) -> "1"=выходной ключ включен
    ;RB2-(CANTx) резерв (шина CAN)
    ;RB3-(CANRx) резерв (шина CAN)
    ;RB4-OUT LED1 -> "1"=светится
    ;RB5-OUT-(DIR-UART)
    ;RB6-x не используется
    ;RB7-x не используется
    ;RC0-IN вход IN1(X7) ->T1
    ;RC1-x вход IN1(X7) ->CCP2
    ;RC2-x вход IN0(X6) ->CCP1
    ;RC3-OUT выход OUT2P(X10-11) -> "1"=выходной ключ включен
    ;RC4-OUT выход OUT2N для второго плеча бистабильного реле(X10-11) -> "1"=выходной ключ включен
    ;RC5-OUT LED2 -> "1"=светится
    ;RC6-OUT-UART
    ;RC7-IN-UART
    ;******************************************************************************
    ;Драйвер загружаемый в модуль MCX51-9.1 поверх основной прошивки Fractal
    ;драйвер инициализирует ресурсы в необходимые режимы,
    ;"сопрягает" ячейки памяти - виртуальные входы и выходы с реальными ресурсами.
    ;Таким образом пользователь может работать непосредственно с ячейками RAM не заботясь
    ;о том какие реальные порты и биты в них надо дергать.

    ;программно все функции:
    ; - аналоговые входы,
    ; - цифровые входы,
    ; - программные счетчики,
    ; - счетчики на аппаратных таймерах
    ; - собственно выходы в режиме медленного ШИМ(всетаки это модуль выходов)
    ;работают одновременно - хочешь используй , не хочешь все-равно есть :)
    ; надо не забывать о положении входных джамперов - они задают реальную схемотехнику входов

    ;В ячейки OUT_x пользователь заносит требуемое состояние выходов,

    ;В ячейке IN_LOG состояние входов IN0, IN1 после устранения дребезга
    ;(после устранения дребезга с периодом дискретизации дискретных входов = PR_IN*1мс)

    ;В ячейках CNT_xx (по 16 бит)производится МЕДЛЕННЫЙ подсчет импульсов с соответствующего входа
    ;(после устранения дребезга с периодом дискретизации дискретных входов = PR_IN*1мс)

    ;В ячейках FR_xx (по 16 бит)производится БЫСТРЫЙ счет импульсов со входов IN0 и IN1
    ;с использованием TMR0 и TMR1 с периодом перезаписи = PER_TMR*1мс

    ;В ячейках ADC_xx (по 10 бит) сохраняется результат измерения напряжения на входах
    ;обновление 1000 раз/сек
    ; используется источник опорного напряжения подключенный Vcc равный 5.0В
    ;###############################################################################
    if TYPE_PIC==1
    LIST P=18F2520, F=INHX32 ;directive to define processor and file format
    #include
    #DEFINE BEG_USER 0x2000
    endif
    if TYPE_PIC==2
    LIST P=18F2620, F=INHX32 ;directive to define processor and file format
    #include
    #DEFINE BEG_USER 0x4000
    endif
    if TYPE_PIC==3
    LIST P=18F4520, F=INHX32 ;directive to define processor and file format
    #include
    #DEFINE BEG_USER 0x2000
    endif
    if TYPE_PIC==4
    LIST P=18F6520, F=INHX32 ;directive to define processor and file format
    #include ;processor specific variable definitions
    #DEFINE BEG_USER 0x2000
    endif
    if TYPE_PIC==5
    LIST P=18F6621, F=INHX32 ;directive to define processor and file format
    #include ;processor specific variable definitions
    #DEFINE BEG_USER 0x4000
    endif
    if TYPE_PIC==6
    LIST P=18F6527, F=INHX32 ;directive to define processor and file format
    #include ;processor specific variable definitions
    #DEFINE BEG_USER 0x2000
    endif
    ;###############################################################################
    CBLOCK 0x000
    OUT_1 ;ADR RAM=0x00 ;регистр состояния выхода OUT0 -> RB0 => X8-9
    ;OUT_1 = 0x00 выключен
    ;OUT_1 = 0xFF включен
    OUT_2 ;ADR RAM=0x01 ;регистр состояния выхода OUT1 -> RB1 => X10-11
    ;OUT_2 = 0x00 выключен
    ;OUT_2 = 0xFF включен
    IN_LOG ;ADR RAM=0x02 ;регистр состояния цифровых входов
    ;Bit 0 => RA4=> IN0=X6
    ;Bit 1 => RC0=> IN1=X7
    PER_TMR ;ADR RAM=0x03 ;ячейка оперативного хранения времени накопления в аппаратных таймерах
    ;пользователь может ее налету менять для изменения времени накопления таймеров
    ;после инициализации в нее заносится значение PER_TMR =100 (мс)
    ;при этом максимальная входная частота = 655 360 Гц, большая частота переполнит счетчик
    ;для работы с большими частотами надо выбирать меньшее время накопления
    ;так, например, для PER_TMR =10 (мс) Fmax=6 553 600 Гц
    PER_IN ;ADR RAM=0x04 ;ячейка оперативного хранения периода дискретизации логических входов
    ;пользователь может ее налету менять для изменения верхней частотной границы
    ;ПРОГРАММНЫХ счетчиков
    ;<=> или времени защиты от дребезга дискретных входов
    ;после инициализации в нее заносится значение PER_IN =10
    ;т.е. время защиты от дребезга = 10мс, верхний предел входной частоты = 50 Гц
    PER_PWM ;ADR RAM=0x05 ;ячейка оперативного хранения дискрета ШИМа
    ;пользователь может ее налету менять для изменения периода ШИМ
    ;после инициализации в нее заносится значение PER_PWM =20 (*1мс)
    ;т.е. один дискрет ШИМ соответствует одному полному периоду частоты сети=50Гц

    ENDC
    CBLOCK 0x010
    FR_0L ;младший байт частоты входа(аппаратный счет TMR0) IN0=X5->RA4
    FR_0H ;старший байт частоты входа(аппаратный счет TMR0) IN0=X5->RA4
    FR_1L ;младший байт частоты входа(аппаратный счет TMR1) IN1=X6->RC0
    FR_1H ;старший байт частоты входа(аппаратный счет TMR1) IN1=X6->RC0
    ENDC
    CBLOCK 0x020
    CNT_0L ;младший байт программного счетчика входа IN0=X5->RA4
    CNT_0H ;старший байт программного счетчика входа IN0=X5->RA4
    CNT_1L ;младший байт программного счетчика входа IN1=X6->RC0
    CNT_1H ;старший байт программного счетчика входа IN1=X6->RC0
    ENDC
    CBLOCK 0x030
    ADC_0L ;младший байт измеренного напряжения IN0=X5->RA0
    ADC_0H ;старшие два бита измеренного напряжения IN0=X5->RA0
    ADC_1L ;младший байт измеренного напряжения IN1=X6->RA1
    ADC_1H ;старший два бита измеренного напряжения IN1=X6->RA1
    ENDC
    ;рабочие ячейки
    CBLOCK 0x040
    IN_OLD ;прошлое значение дискретных входов (используется для устанения дребезга)
    TMR_FR ;таймер для задания частоты дискретизации частотных входов
    TMR_IN ;таймер для задания частоты дискретизации дискретных входов
    ; TMR_PWM ;таймер для создания дискрета медленного ШИМ
    PWM_COU ;счетчик тактов ШИМ
    ENDC

    ;константы
    PER_TMR_K EQU D'100' ;период дискретизации для частотных входов = 100*1мс=100мс
    PER_IN_K EQU D'10' ;период дискретизации дискретных входов = 10*1мс=10мс
    ;PER_PWM_K EQU D'20' ;величина дискрета медленного ШИМа = 20*1мс=20мс

    #DEFINE PIN_IN_0 PORTA,4 ;логический вход IN0
    #DEFINE PIN_IN_1 PORTC,0 ;логический вход IN1
    #DEFINE PIN_LED_1 LATB,4 ;светодиод OUT1: 0=>off, 1=>on
    #DEFINE PIN_LED_2 LATC,5 ;светодиод OUT2: 0=>off, 1=>on
    #DEFINE PIN_OUT_1 LATB,0 ;выход на ключ OUT1: 0=>off, 1=>on
    #DEFINE PIN_OUT_2 LATC,3 ;выход на ключ OUT2: 0=>off, 1=>on

    ;******************************************************************************
    ;Таблица пользовательских векторов
    ;достаточно определить переменную VECT
    #DEFINE VECT 0x00C4
    ;0x0080 ;REG_USER<7>=1 передать управление на адрес BEG_USER + 0x00 после инициализации контроллера
    ;0x0040 ;REG_USER<6>=1 передать управление на адрес BEG_USER + 0x04 перед завершением цикла MAIN
    ;0x0020 ;REG_USER<5>=1 передать управление на адрес BEG_USER + 0x08 после обработки IntHi 10 000 Гц
    ;0x0010 ;REG_USER<4>=1 передать управление на адрес BEG_USER + 0x0C после обработки IntLo
    ;0x0008 ;REG_USER<3>=1 передать управление на адрес BEG_USER + 0x10 для дальнейшей обработки команд MODBUS
    ;0x0004 ;REG_USER<2>=1 передать управление на адрес BEG_USER + 0x14 после обработки IntHi 1000 Гц
    ;0x0002 ;REG_USER<1>=1 передать управление на адрес BEG_USER + 0x18 после обработки IntHi 100 Гц
    ;0x0001 ;REG_USER<0>=1 передать управление на адрес BEG_USER + 0x1C выполнить один раз
    ;0x8000 ;REG_USER2<7>=1 передать управление на адрес BEG_USER + 0x20 до обработки HiInt
    ;0x4000 ;REG_USER2<6>=1 передать управление на адрес BEG_USER + 0x24 до обработки LoInt

    ORG BEG_USER + 0x00 ;точка входа после инициализации (REG_USER<7>=1)
    if low VECT & B'10000000'
    goto Init
    else
    return
    endif
    ORG BEG_USER + 0x04 ;точка входа Main (REG_USER<6>=1)
    if low VECT & B'01000000'
    goto Main
    else
    return
    endif
    ORG BEG_USER + 0x08 ;точка входа 10 000гц или после Hi_Int (REG_USER<5>=1)
    if low VECT & B'00100000'
    goto HiInt
    else
    return
    endif
    ORG BEG_USER + 0x0C ;точка входа после Lo_Int (REG_USER<4>=1)
    if low VECT & B'00010000'
    goto LoInt
    else
    return
    endif
    ORG BEG_USER + 0x10 ;точка входа после Modbus (REG_USER<3>=1)
    if low VECT & B'00001000'
    goto Modbus
    else
    return
    endif
    ORG BEG_USER + 0x14 ;точка входа 1 000гц (REG_USER<2>=1)
    if low VECT & B'00000100'
    goto T1000Hz
    else
    return
    endif
    ORG BEG_USER + 0x18 ;точка входа 100гц (REG_USER<1>=1)
    if low VECT & B'00000010'
    goto T100Hz
    else
    return
    endif
    ORG BEG_USER + 0x1C ;точка входа выполнить один раз (REG_USER<0>=1)
    if low VECT & B'00000001'
    goto One
    else
    return
    endif
    ORG BEG_USER + 0x20 ;точка входа перед обработкой Hi_Int (REG_USER2<7>=1)
    if high VECT & B'10000000'
    goto PreHi
    else
    return
    endif
    ORG BEG_USER + 0x24 ;точка входа перед обработкой Lo_Int (REG_USER2<6>=1)
    if high VECT & B'01000000'
    goto PreLo
    else
    return
    endif
    ;***************************************************************************
    ORG BEG_USER + 0x40
    ;Инициализация
    Init ;зададим конфигурацию контроллера
    ;PORTA
    movlw B'11111111' ;все входы
    movwf TRISA
    ;PORTB
    bcf PIN_OUT_1 ;обнулим линии чтобы чего случайно не включить
    bcf PIN_LED_1
    bcf TRISB,0 ;направим линии
    bcf TRISB,4
    ;PORTC
    ;аккуратненько проинициализируем нужные биты
    bsf TRISC,RC0 ;развернем на вход
    bsf TRISC,RC1 ;развернем на вход
    bsf TRISC,RC2 ;развернем на вход

    bcf PIN_OUT_2 ;обнулим линии
    bcf PIN_LED_2
    bcf TRISC,3 ;направим линии
    bcf TRISC,5
    ;ADC
    movlw B'00001101' ;AN0,AN1 -> аналаговые, опора от питания
    movwf ADCON1
    movlw B'10010010' ;правое выравнивание,пред-пауза=4*Tad,Tad=Fosc/32(общее время=16мкс)
    movwf ADCON2
    movlw B'00000001' ;АЦП включен
    movwf ADCON0

    ;TMR0 ;будет считать импульсы с X5->RA4
    movlw B'10101000' ;включить,16бит,внешний вход,фронт,без предделителя...
    movwf T0CON
    clrf TMR0H ;почистим таймер
    clrf TMR0L
    ;TMR1 ;будет считать импульсы с X6->RC0
    movlw B'10000011' ;16бит,-,1:1,,генератор выкл,синхронизировать,внешний вход,включить
    movwf T1CON
    clrf TMR1H ;почистим таймер
    clrf TMR1L

    lfsr FSR0,0x000 ;почистим RAM c 0x000 по 0x04F
    Init_1 clrf POSTINC0
    btfss FSR0L,6
    bra Init_1
    btfss FSR0L,4
    bra Init_1

    movlw PER_TMR_K ;занесем константы в RAM
    movwf PER_TMR
    movlw PER_IN_K
    movwf PER_IN

    return
    ;***************************************************************************
    ;Время
    T1000Hz ;попадаем сюда каждые 10мс
    movlw B'00000011' ;запустим преобразование 0-го канала
    movwf ADCON0
    ;займемся временем все- равно ждем
    tstfsz TMR_FR ;если таймер еще не обнулен - будем вычитать каждую 1мс
    decf TMR_FR,f
    tstfsz TMR_IN ;если таймер еще не обнулен - будем вычитать каждую 1мс
    decf TMR_IN,f

    Int1000_1 btfsc ADCON0,GO_DONE ;ждем-с 16 мкс
    bra Int1000_1
    movff ADRESL,ADC_0L ;запоминаем результат
    movff ADRESH,ADC_0H

    movlw B'00000111' ;запустим преобразование 1-го канала
    movwf ADCON0
    Int1000_2 btfsc ADCON0,GO_DONE ;ждем-с 16 мкс
    bra Int1000_2
    movff ADRESL,ADC_1L ;запоминаем результат
    movff ADRESH,ADC_1H

    return
    ;PS
    ;если бы мы здесь воспользовались например вектором 10 мс
    ;то время бы шло в 10 раз медленее
    ;***************************************************************************
    Main tstfsz TMR_FR ;проверим пришло ли время обработать частотные входы
    bra Mn_1

    movff PER_TMR,TMR_FR ;да, перевзведем таймер
    ;таймеры работают в 16-битном режиме, поэтому нагло копируем их, соблюдая последовательность H<->L
    bcf INTCON,GIEL ;запретим ненадолго прерывания по интерфейсам,чтобы не считали ложные данные

    movff TMR0L,FR_0L ;скопируем накопленное значение в RAM
    movff TMR0H,FR_0H
    clrf TMR0H ;очистим
    clrf TMR0L

    movff TMR1L,FR_1L ;скопируем накопленное значение в RAM
    movff TMR1H,FR_1H
    clrf TMR1H ;очистим
    clrf TMR1L

    bsf INTCON,GIEL ;вернем прерывание
    ;с частотами ВСЕ!

    Mn_1 tstfsz TMR_IN ;проверим пришло ли время обработать дискретные входы
    return ;нет , уходим

    movff PER_IN,TMR_IN ;да, перевзведем таймер

    bcf INTCON,GIEL ;запретим ненадолго прерывания по интерфейсам,чтобы не считали ложные данные

    clrf IN_LOG ;подготовим ячейку

    btfsc PIN_IN_0 ;IN0
    bsf IN_LOG,0 ;есть сигнал
    btfsc PIN_IN_1 ;IN1
    bsf IN_LOG,1 ;есть сигнал

    ;со статическим состоянием входов ВСЕ.

    movf IN_LOG,w
    xorwf IN_OLD,w ;определим изменения с прошлым вводом
    andwf IN_LOG,w ;посмотрим какие из них были фронты
    ;сделаем разбор
    btfss WREG,0 ;проверим бит 0
    bra Mn_2 ;пусто
    incf CNT_0L,f ;здесь только-что был фронт, нарастим счетчик
    bnc Mn_2 ;проверим перенос
    incf CNT_0H,f

    Mn_2 btfss WREG,1 ;проверим бит 1
    bra Mn_3 ;пусто
    incf CNT_1L,f ;здесь только-что был фронт, нарастим счетчик
    bnc Mn_3 ;проверим перенос
    incf CNT_1H,f

    Mn_3 movff IN_LOG,IN_OLD ;занесем текущее значение входов для обработки на следующем шаге

    bsf INTCON,GIEL ;вернем прерывание

    ;займемся выходами
    tstfsz OUT_1
    bra Mn_4
    bcf PIN_OUT_1 ;выключим выход 1
    bcf PIN_LED_1 ;выключим светодиод
    bra Mn_5
    Mn_4 bsf PIN_OUT_1 ;включим выход 1
    bsf PIN_LED_1 ;ыключим светодиод

    Mn_5 tstfsz OUT_2
    bra Mn_6
    bcf PIN_OUT_2 ;выключим выход 2
    bcf PIN_LED_2 ;выключим светодиод
    bra Mn_7
    Mn_6 bsf PIN_OUT_2 ;включим выход 2
    bsf PIN_LED_2 ;ыключим светодиод

    Mn_7 return

    ;;*************************************************************************;
    ;Служебная область EEPROM:
    ;(0xF0)<= младший байт версии драйвера
    ;(0xF1)<= старший байт версии драйвера
    ;(0xF6)<= младший байт скорости UART2 (для 115200: для PIC18F6520 =>0x10; для PIC18F6621 =>0x43);для PIC18F6527 =>0x44)
    ;(0xF7)<= старший байт скорости UART2 (для 115200 ==>0x00)
    ;(0xF8)<= ((адрес второго I2C))
    ;(0xF9)<= адрес UART2
    ;(0xFA)<= младший вектор пользователя (для данной программы => 0xA0)
    ;(0xFB)<= старший вектор пользователя ==>0x00
    ;(0xFC)<= младший байт скорости UART1 (для 115200: для PIC18F6520 =>0x10; для PIC18F6621 =>0x43);для PIC18F6527 =>0x44)
    ;(0xFD)<= старший байт скорости UART1 (для 115200 ==>0x00)
    ;(0xFE)<= адрес I2C
    ;(0xFF)<= адрес UART1
    ORG 0xF000F0
    DE low VERS, high VERS
    ORG 0xF000FA
    DE low VECT, high VECT
    ;*************************************************************************;
    ;End of program
    END

    Состояние Вашей корзины:

    Позиций: 0
    Количество: 0
    Сумма заказа: 0
    Оформить заказ

      Выставки

    MCU32-1

    модуль вычислителя промышленный контроллер
  • Микроконтроллер - STM32F103RET6
  • Разрядность - 32 бит
  • Быстродействие 72 MHz / 1.25 DMIPS/MHz (Dhrystone 2.1)
  • Flash 512 Кбайт
  • RAM 64 Кбайт
  • АЦП 3 АЦП 12 бит 1мкс
  • ЦАП 2 ЦАП 12бит
  • ПДП 12 каналов
  • Отладочный разъем Serial wire debug (SWD)
  • Интерфейсы USB, RS485, CAN, I2C, SPI, MicroLan
  • Часы реального времени
  • Питание +5В
  • Размер 25.4 * 76.2 * 13 мм

  • MCX53-32.x DIN

    программируемый логический контроллер
  • Микроконтроллер STM32F103RET6
  • Встроенный однокристальный Fractal-BASIC-Cortex
  • Интерфейсы без развязки - USB, RS485/CAN, I2C, SPI, MicroLan
  • Гальванически развязанные интерфейсы - RS485, MicroLan DS2482-100
  • Часы реального времени с литиевым элементом
  • Универсальные сигнальные входо-выходы - 12
  • Силовые выходы  - 8
  • Питание +9...24В
  • Габариты узла в DIN конструктиве - 105x86x58
  • Главная страница :: Новости :: Прайс-лист :: FAQ :: Обмен опытом :: Ссылки :: О фирме :: Как нас найти :: Как купить :: Полный список модулей :: Преобразователи интерфейсов / Репитеры :: Интерфейсные модули :: Вычислители :: Узлы автоматизации :: Модули входов :: Модули выходов :: Модули аналогового входа/выхода :: Модули питания :: Кроссы, Макетные модули, Переходные модули :: Другие модули ::

    postmaster@fractal.com.ru
    Copyright © 1999-2018 ООО "Фрактал"

    Яндекс цитирования Rambler's Top100
    19608
    210
    5
    2